home *** CD-ROM | disk | FTP | other *** search
/ Clickx 115 / Clickx 115.iso / software / tools / windows / tails-i386-0.16.iso / live / filesystem.squashfs / usr / share / GNUstep / Makefiles / GNUstep.csh < prev    next >
Encoding:
Text File  |  2010-05-31  |  13.6 KB  |  420 lines
  1. #   This file must be sourced inside csh using: source
  2. #
  3. #   GNUstep.csh.  Generated from GNUstep.csh.in by configure.
  4. #
  5. #   Shell initialization for the GNUstep environment.
  6. #
  7. #   Copyright (C) 1998-2008 Free Software Foundation, Inc.
  8. #
  9. #   Author:  Scott Christley <scottc@net-community.com>
  10. #   Author:  Adam Fedor <fedor@gnu.org>
  11. #   Author:  Richard Frith-Macdonald <rfm@gnu.org>
  12. #   Author:  Nicola Pero <nicola.pero@meta-innovation.com>
  13. #
  14. #   This file is part of the GNUstep Makefile Package.
  15. #
  16. #   This library is free software; you can redistribute it and/or
  17. #   modify it under the terms of the GNU General Public License
  18. #   as published by the Free Software Foundation; either version 3
  19. #   of the License, or (at your option) any later version.
  20. #   
  21. #   You should have received a copy of the GNU General Public
  22. #   License along with this library; see the file COPYING.
  23. #   If not, write to the Free Software Foundation,
  24. #   51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  25. #
  26.  
  27. # When this is set to 'yes', strict gnustep-make v2 compatibility mode
  28. # is turned on.
  29. set GNUSTEP_MAKE_STRICT_V2_MODE=no
  30.  
  31. #
  32. # Read our configuration files
  33. #
  34.  
  35. # Determine the location of the system configuration file
  36. if ( ! ${?GNUSTEP_CONFIG_FILE} ) then
  37.   setenv GNUSTEP_CONFIG_FILE "/etc/GNUstep/GNUstep.conf"
  38. else
  39.   set GNUSTEP_KEEP_CONFIG_FILE=yes
  40. endif
  41.  
  42. # Determine the location of the user configuration file
  43. if ( ! ${?GNUSTEP_USER_CONFIG_FILE} ) then
  44.   setenv GNUSTEP_USER_CONFIG_FILE ".GNUstep.conf"
  45. else
  46.   set GNUSTEP_KEEP_USER_CONFIG_FILE=yes
  47. endif
  48.  
  49. # Read the system configuration file
  50. if ( -e "${GNUSTEP_CONFIG_FILE}" ) then
  51.   #
  52.   # Convert the config file from sh syntax to csh syntax, and execute it.
  53.   #
  54.   # We want to convert every line of the type ^xxx=yyy$ into setenv xxx yyy;
  55.   # and ignore any other line.
  56.   #
  57.   # This sed expression will first delete all lines that don't match
  58.   # the pattern ^[^#=][^#=]*=.*$ -- which means "start of line (^),
  59.   # followed by a character that is not # and not = ([^#=]), followed
  60.   # by 0 or more characters that are not # and not = ([^#=]*),
  61.   # followed by a = (=), followed by some characters until end of the
  62.   # line (.*$).  It will then replace each occurrence of the same
  63.   # pattern (where the first and second relevant parts are now tagged
  64.   # -- that's what the additional \(...\) do) with 'setenv \1 \2'.
  65.   #
  66.   # The result of all this is ... something that we want to execute!
  67.   # We use eval to execute the results of `...`.
  68.   #
  69.   # Please note that ! must always be escaped in csh, which is why we
  70.   # write \\!
  71.   #
  72.   # Also note that we add a ';' at the end of each setenv command so
  73.   # that we can pipe all the commands through a single eval.
  74.   #
  75.   eval `sed -e '/^[^#=][^#=]*=.*$/\\!d' -e 's/^\([^#=][^#=]*\)=\(.*\)$/setenv \1 \2;/' "${GNUSTEP_CONFIG_FILE}"`
  76. endif
  77.  
  78. # FIXME: determining GNUSTEP_HOME
  79. set GNUSTEP_HOME = ~
  80.  
  81. # Read the user configuration file ... unless it is disabled (ie, set
  82. # to an empty string)
  83. if ( ${?GNUSTEP_USER_CONFIG_FILE} ) then
  84.   switch ("${GNUSTEP_USER_CONFIG_FILE}")
  85.    case /*: # An absolute path
  86.      if ( -e "${GNUSTEP_USER_CONFIG_FILE}" ) then
  87.       # See above for an explanation of the sed expression
  88.       eval `sed -e '/^[^#=][^#=]*=.*$/\\!d' -e 's/^\([^#=][^#=]*\)=\(.*\)$/setenv \1 \2;/' "${GNUSTEP_USER_CONFIG_FILE}"`
  89.      endif
  90.      breaksw
  91.    default: # Something else
  92.      if ( -e "${GNUSTEP_HOME}/${GNUSTEP_USER_CONFIG_FILE}" ) then
  93.        eval `sed -e '/^[^#=][^#=]*=.*$/\\!d' -e 's/^\([^#=][^#=]*\)=\(.*\)$/setenv \1 \2;/' "${GNUSTEP_HOME}/${GNUSTEP_USER_CONFIG_FILE}"`
  94.      endif
  95.      breaksw
  96.    endsw
  97. endif
  98.  
  99. # Now, set any essential variable (that is not already set) to the
  100. # built-in values.
  101. if ( "${GNUSTEP_MAKE_STRICT_V2_MODE}" == "yes" ) then
  102.   unsetenv GNUSTEP_SYSTEM_ROOT
  103.   unsetenv GNUSTEP_LOCAL_ROOT
  104.   unsetenv GNUSTEP_NETWORK_ROOT
  105.   unsetenv GNUSTEP_FLATTENED
  106. else
  107.   if ( ! ${?GNUSTEP_SYSTEM_ROOT} ) then
  108.     setenv GNUSTEP_SYSTEM_ROOT "/usr/System"
  109.   endif
  110.  
  111.   if ( ! ${?GNUSTEP_LOCAL_ROOT} ) then
  112.     setenv GNUSTEP_LOCAL_ROOT "/usr/Local"
  113.   endif
  114.  
  115.   if ( ! ${?GNUSTEP_NETWORK_ROOT} ) then
  116.     setenv GNUSTEP_NETWORK_ROOT "/usr/Network"
  117.   endif
  118.  
  119.   # GNUSTEP_FLATTENED is obsolete, please use GNUSTEP_IS_FLATTENED
  120.   # instead
  121.   setenv GNUSTEP_FLATTENED "yes"
  122. endif
  123.  
  124. setenv GNUSTEP_IS_FLATTENED "yes"
  125. if ( ! ${?LIBRARY_COMBO} ) then
  126.   setenv LIBRARY_COMBO "gnu-gnu-gnu"
  127. endif
  128.  
  129. if ( ! ${?GNUSTEP_MAKEFILES} ) then
  130.   setenv GNUSTEP_MAKEFILES "/usr/share/GNUstep/Makefiles"
  131. endif
  132.  
  133. if ( "${GNUSTEP_MAKE_STRICT_V2_MODE}" == "yes" ) then
  134.   unsetenv GNUSTEP_USER_DIR
  135.   unsetenv GNUSTEP_USER_ROOT
  136. else
  137.   if ( ! ${?GNUSTEP_USER_DIR} ) then
  138.     setenv GNUSTEP_USER_DIR "GNUstep"
  139.   endif
  140.  
  141.   #
  142.   # Set GNUSTEP_USER_ROOT which is the variable used in practice
  143.   #
  144.   switch ("${GNUSTEP_USER_DIR}")
  145.    case /*: # An absolute path
  146.      setenv GNUSTEP_USER_ROOT "${GNUSTEP_USER_DIR}"
  147.      breaksw
  148.    default: # Something else
  149.      setenv GNUSTEP_USER_ROOT "${GNUSTEP_HOME}/${GNUSTEP_USER_DIR}"
  150.      breaksw
  151.   endsw
  152.  
  153.   unsetenv GNUSTEP_USER_DIR
  154. endif
  155.  
  156. if ( "" == "" ) then
  157.   setenv GNUSTEP_HOST "i486-pc-linux-gnu"
  158.   setenv GNUSTEP_HOST_CPU "ix86"
  159.   setenv GNUSTEP_HOST_VENDOR "pc"
  160.   setenv GNUSTEP_HOST_OS "linux-gnu"
  161. endif
  162.  
  163. #
  164. # Determine the host information
  165. #
  166. if ( ! ${?GNUSTEP_HOST} ) then
  167.   pushd /tmp > /dev/null
  168.   setenv GNUSTEP_HOST `${GNUSTEP_MAKEFILES}/config.guess`
  169.   setenv GNUSTEP_HOST `${GNUSTEP_MAKEFILES}/config.sub ${GNUSTEP_HOST}`
  170.   popd > /dev/null
  171. endif
  172.  
  173. if ( ! ${?GNUSTEP_HOST_CPU} ) then
  174.   setenv GNUSTEP_HOST_CPU `${GNUSTEP_MAKEFILES}/cpu.sh ${GNUSTEP_HOST}`
  175.   setenv GNUSTEP_HOST_CPU `${GNUSTEP_MAKEFILES}/clean_cpu.sh ${GNUSTEP_HOST_CPU}`
  176. endif
  177.  
  178. if ( ! ${?GNUSTEP_HOST_VENDOR} ) then
  179.   setenv GNUSTEP_HOST_VENDOR `${GNUSTEP_MAKEFILES}/vendor.sh ${GNUSTEP_HOST}`
  180.   setenv GNUSTEP_HOST_VENDOR `${GNUSTEP_MAKEFILES}/clean_vendor.sh ${GNUSTEP_HOST_VENDOR}`
  181. endif
  182.  
  183. if ( ! ${?GNUSTEP_HOST_OS} ) then
  184.   setenv GNUSTEP_HOST_OS `${GNUSTEP_MAKEFILES}/os.sh ${GNUSTEP_HOST}`
  185.   setenv GNUSTEP_HOST_OS `${GNUSTEP_MAKEFILES}/clean_os.sh ${GNUSTEP_HOST_OS}`
  186. endif
  187.  
  188. # Now load in all the remaining paths
  189. source "${GNUSTEP_MAKEFILES}/filesystem.csh"
  190.  
  191. # No longer needed
  192. unset GNUSTEP_HOME
  193.  
  194. # Determine if the paths look like Windows paths that need fixing
  195. set fixup_paths=no
  196. if ( `echo $GNUSTEP_MAKEFILES | sed 's|^[a-zA-Z]:/.*$||'` == "" ) then
  197.   set fixup_paths=yes
  198. endif
  199.  
  200. #
  201. # Add the GNUstep tools directories to the path
  202. #
  203. if ( "${GNUSTEP_MAKE_STRICT_V2_MODE}" == "no" ) then
  204.   if ( ! ${?GNUSTEP_PATHLIST} ) then
  205.    setenv GNUSTEP_PATHLIST `$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_ROOT" "$GNUSTEP_LOCAL_ROOT" "$GNUSTEP_NETWORK_ROOT" "$GNUSTEP_SYSTEM_ROOT" $fixup_paths`
  206.   endif
  207. endif
  208.  
  209. set GNUSTEP_TOOLS_PATHLIST=`$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_TOOLS" "$GNUSTEP_LOCAL_TOOLS" "$GNUSTEP_NETWORK_TOOLS" "$GNUSTEP_SYSTEM_TOOLS" $fixup_paths`
  210.  
  211. foreach dir ( "${GNUSTEP_SYSTEM_ADMIN_TOOLS}" "${GNUSTEP_NETWORK_ADMIN_TOOLS}" "${GNUSTEP_LOCAL_ADMIN_TOOLS}" "${GNUSTEP_USER_ADMIN_TOOLS}" )
  212.   if ( -d "${dir}"  &&  -w "${dir}" ) then
  213.     if ( { (echo ":${GNUSTEP_TOOLS_PATHLIST}:"\
  214.       |grep -v ":${dir}:" >/dev/null) } ) then
  215.       setenv GNUSTEP_TOOLS_PATHLIST "${dir}:${GNUSTEP_TOOLS_PATHLIST}"
  216.     endif
  217.   endif
  218. end
  219.  
  220. foreach dir ( `/bin/sh -c 'IFS=:; for i in '"${GNUSTEP_TOOLS_PATHLIST}"'; do echo $i; done'` )
  221.   set path_fragment="${dir}"
  222.   if ( "${GNUSTEP_IS_FLATTENED}" == "no" ) then
  223.     set path_fragment="${dir}:${dir}/${GNUSTEP_HOST_CPU}/${GNUSTEP_HOST_OS}/${LIBRARY_COMBO}:${dir}/${GNUSTEP_HOST_CPU}/${GNUSTEP_HOST_OS}"
  224.   endif
  225.  
  226.   if ( ! ${?PATH} ) then
  227.     setenv PATH "${path_fragment}"
  228.   else if ( { (echo ":${PATH}:"\
  229.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  230.     setenv PATH "${path_fragment}:${PATH}"
  231.   endif
  232. end
  233. unset path_fragment dir
  234. unset GNUSTEP_TOOLS_PATHLIST
  235.  
  236. set GNUSTEP_LIBRARIES_PATHLIST=`$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_LIBRARIES" "$GNUSTEP_LOCAL_LIBRARIES" "$GNUSTEP_NETWORK_LIBRARIES" "$GNUSTEP_SYSTEM_LIBRARIES" $fixup_paths`
  237. foreach dir ( `/bin/sh -c 'IFS=:; for i in '"${GNUSTEP_LIBRARIES_PATHLIST}"'; do echo $i; done'` )
  238.   if ( "$GNUSTEP_IS_FLATTENED" == "yes" ) then
  239.     set path_fragment="$dir"
  240.   else
  241.     set path_fragment="$dir/$GNUSTEP_HOST_CPU/$GNUSTEP_HOST_OS/$LIBRARY_COMBO:$dir/$GNUSTEP_HOST_CPU/$GNUSTEP_HOST_OS"
  242.   endif
  243.  
  244.   switch ( "${GNUSTEP_HOST_OS}" )
  245.  
  246.     case *nextstep4* :
  247.     case *darwin* :
  248.       if ( $?DYLD_LIBRARY_PATH == 0 ) then
  249.       setenv DYLD_LIBRARY_PATH "${path_fragment}"
  250.       else if ( { (echo ":${DYLD_LIBRARY_PATH}:"\
  251.         |grep -v ":${path_fragment}:" >/dev/null) } ) then
  252.       setenv DYLD_LIBRARY_PATH "${path_fragment}:${DYLD_LIBRARY_PATH}"
  253.       endif
  254.       breaksw
  255.  
  256.     case *hpux* :
  257.       if ( $?SHLIB_PATH == 0 ) then
  258.       setenv SHLIB_PATH "${path_fragment}"
  259.       else if ( { (echo ":${SHLIB_PATH}:"\
  260.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  261.       setenv SHLIB_PATH "${path_fragment}:${SHLIB_PATH}"
  262.       endif
  263.  
  264.       if ( $?LD_LIBRARY_PATH == 0 ) then
  265.       setenv LD_LIBRARY_PATH "${path_fragment}"
  266.       else if ( { (echo ":${LD_LIBRARY_PATH}:"\
  267.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  268.       setenv LD_LIBRARY_PATH "${path_fragment}:${LD_LIBRARY_PATH}"
  269.       endif
  270.  
  271.       breaksw
  272.  
  273.     case * :
  274.       if ( $?LD_LIBRARY_PATH == 0 ) then
  275.       setenv LD_LIBRARY_PATH "${path_fragment}"
  276.       else if ( { (echo ":${LD_LIBRARY_PATH}:"\
  277.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  278.       setenv LD_LIBRARY_PATH "${path_fragment}:${LD_LIBRARY_PATH}"
  279.       endif
  280.  
  281.       breaksw
  282.   endsw
  283. end
  284. unset path_fragment dir
  285. unset GNUSTEP_LIBRARIES_PATHLIST
  286.  
  287. switch ( "${GNUSTEP_HOST_OS}" )
  288.   case *darwin* :
  289.     set GNUSTEP_FRAMEWORKS_PATHLIST=`$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_LIBRARY/Frameworks" "$GNUSTEP_LOCAL_LIBRARY/Frameworks" "$GNUSTEP_NETWORK_LIBRARY/Frameworks" "$GNUSTEP_SYSTEM_LIBRARY/Frameworks" $fixup_paths`
  290.     foreach dir ( `/bin/sh -c 'IFS=:; for i in '"${GNUSTEP_FRAMEWORKS_PATHLIST}"'; do echo $i; done'` )
  291.       set path_fragment="$dir"
  292.       if ( $?DYLD_FRAMEWORK_PATH == 0 ) then
  293.         setenv DYLD_FRAMEWORK_PATH "${path_fragment}"
  294.       else if ( { (echo ":${DYLD_FRAMEWORK_PATH}:"\
  295.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  296.         setenv DYLD_FRAMEWORK_PATH "${path_fragment}:${DYLD_FRAMEWORK_PATH}"
  297.       endif
  298.     end
  299.     unset dir path_fragment
  300.     unset GNUSTEP_FRAMEWORKS_PATHLIST
  301.     breaksw
  302.   case * :
  303.     breaksw
  304. endsw
  305.  
  306. set GNUSTEP_LIBRARY_PATHLIST=`$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_LIBRARY" "$GNUSTEP_LOCAL_LIBRARY" "$GNUSTEP_NETWORK_LIBRARY" "$GNUSTEP_SYSTEM_LIBRARY" $fixup_paths`
  307.  
  308. foreach dir ( `/bin/sh -c 'IFS=:; for i in '"${GNUSTEP_LIBRARY_PATHLIST}"'; do echo $i; done'` )
  309.  
  310.   set path_fragment="${dir}/Libraries/Java"
  311.   if ( ! ${?CLASSPATH} ) then
  312.     setenv CLASSPATH "${path_fragment}"
  313.   else if ( { (echo ":${CLASSPATH}:"\
  314.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  315.     setenv CLASSPATH "${CLASSPATH}:${path_fragment}"
  316.   endif
  317.  
  318.   set path_fragment="${dir}/Libraries/Guile"
  319.   if ( ! ${?GUILE_LOAD_PATH} ) then
  320.     setenv GUILE_LOAD_PATH "${path_fragment}"
  321.   else if ( { (echo ":${GUILE_LOAD_PATH}:"\
  322.     |grep -v ":${path_fragment}:" >/dev/null) } ) then
  323.     setenv GUILE_LOAD_PATH "${path_fragment}:${GUILE_LOAD_PATH}"
  324.   endif
  325.  
  326. end
  327. unset path_fragment dir
  328. unset GNUSTEP_TOOLS_PATHLIST
  329.  
  330. set GNUSTEP_INFO_PATHLIST=`$GNUSTEP_MAKEFILES/print_unique_pathlist.sh "$GNUSTEP_USER_DOC_INFO" "$GNUSTEP_LOCAL_DOC_INFO" "$GNUSTEP_NETWORK_DOC_INFO" "$GNUSTEP_SYSTEM_DOC_INFO" $fixup_paths`
  331.  
  332. foreach dir ( `/bin/sh -c 'IFS=:; for i in '"${GNUSTEP_INFO_PATHLIST}"'; do echo $i; done'` )
  333.  
  334.   if ( ! ${?INFOPATH} ) then
  335.     setenv INFOPATH "${dir}:"
  336.   else if ( { (echo ":${INFOPATH}:"\
  337.     |grep -v ":${dir}:" >/dev/null) } ) then
  338.     setenv INFOPATH "${INFOPATH}:${dir}:"
  339.   endif
  340.  
  341. end
  342.  
  343. unset dir
  344.  
  345. if ( "${GNUSTEP_MAKE_STRICT_V2_MODE}" == "yes" ) then
  346.   unsetenv GNUSTEP_IS_FLATTENED
  347.   unsetenv LIBRARY_COMBO
  348.   unsetenv GNUSTEP_HOST
  349.   unsetenv GNUSTEP_HOST_CPU
  350.   unsetenv GNUSTEP_HOST_VENDOR
  351.   unsetenv GNUSTEP_HOST_OS
  352. endif
  353.  
  354. unset GNUSTEP_MAKE_STRICT_V2_MODE
  355.  
  356. if ( ! {$?GNUSTEP_KEEP_CONFIG_FILE} ) then
  357.   unsetenv GNUSTEP_CONFIG_FILE
  358. endif
  359. unset GNUSTEP_KEEP_CONFIG_FILE
  360.  
  361. if ( ! ${?GNUSTEP_KEEP_USER_CONFIG_FILE} ) then
  362.   unsetenv GNUSTEP_USER_CONFIG_FILE
  363. endif
  364. unset GNUSTEP_KEEP_USER_CONFIG_FILE
  365.  
  366. unsetenv GNUSTEP_USER_DEFAULTS_DIR
  367.  
  368. unsetenv GNUSTEP_SYSTEM_APPS 
  369. unsetenv GNUSTEP_SYSTEM_ADMIN_APPS 
  370. unsetenv GNUSTEP_SYSTEM_WEB_APPS 
  371. unsetenv GNUSTEP_SYSTEM_TOOLS 
  372. unsetenv GNUSTEP_SYSTEM_ADMIN_TOOLS 
  373. unsetenv GNUSTEP_SYSTEM_LIBRARY
  374. unsetenv GNUSTEP_SYSTEM_HEADERS 
  375. unsetenv GNUSTEP_SYSTEM_LIBRARIES 
  376. unsetenv GNUSTEP_SYSTEM_DOC 
  377. unsetenv GNUSTEP_SYSTEM_DOC_MAN
  378. unsetenv GNUSTEP_SYSTEM_DOC_INFO
  379.  
  380. unsetenv GNUSTEP_NETWORK_APPS 
  381. unsetenv GNUSTEP_NETWORK_ADMIN_APPS 
  382. unsetenv GNUSTEP_NETWORK_WEB_APPS 
  383. unsetenv GNUSTEP_NETWORK_TOOLS 
  384. unsetenv GNUSTEP_NETWORK_ADMIN_TOOLS
  385. unsetenv GNUSTEP_NETWORK_LIBRARY
  386. unsetenv GNUSTEP_NETWORK_HEADERS 
  387. unsetenv GNUSTEP_NETWORK_LIBRARIES 
  388. unsetenv GNUSTEP_NETWORK_DOC 
  389. unsetenv GNUSTEP_NETWORK_DOC_MAN
  390. unsetenv GNUSTEP_NETWORK_DOC_INFO
  391.  
  392. unsetenv GNUSTEP_LOCAL_APPS 
  393. unsetenv GNUSTEP_LOCAL_ADMIN_APPS 
  394. unsetenv GNUSTEP_LOCAL_WEB_APPS 
  395. unsetenv GNUSTEP_LOCAL_TOOLS 
  396. unsetenv GNUSTEP_LOCAL_ADMIN_TOOLS
  397. unsetenv GNUSTEP_LOCAL_LIBRARY
  398. unsetenv GNUSTEP_LOCAL_HEADERS 
  399. unsetenv GNUSTEP_LOCAL_LIBRARIES 
  400. unsetenv GNUSTEP_LOCAL_DOC 
  401. unsetenv GNUSTEP_LOCAL_DOC_MAN
  402. unsetenv GNUSTEP_LOCAL_DOC_INFO
  403.  
  404. unsetenv GNUSTEP_USER_APPS 
  405. unsetenv GNUSTEP_USER_ADMIN_APPS
  406. unsetenv GNUSTEP_USER_WEB_APPS
  407. unsetenv GNUSTEP_USER_TOOLS 
  408. unsetenv GNUSTEP_USER_ADMIN_TOOLS 
  409. unsetenv GNUSTEP_USER_LIBRARY
  410. unsetenv GNUSTEP_USER_HEADERS 
  411. unsetenv GNUSTEP_USER_LIBRARIES 
  412. unsetenv GNUSTEP_USER_DOC 
  413. unsetenv GNUSTEP_USER_DOC_MAN
  414. unsetenv GNUSTEP_USER_DOC_INFO
  415.  
  416. unsetenv GNUSTEP_SYSTEM_USERS_DIR
  417. unsetenv GNUSTEP_LOCAL_USERS_DIR
  418. unsetenv GNUSTEP_NETWORK_USERS_DIR
  419.  
  420.